Tutorial

We present a typical workflow with DifferentiationInterfaceTest.jl, building on the tutorial of the DifferentiationInterface.jl documentation (which we encourage you to read first).

julia> using DifferentiationInterface, DifferentiationInterfaceTest
julia> import ForwardDiff, Zygote

Introduction

The AD backends we want to compare are ForwardDiff.jl and Enzyme.jl.

backends = [AutoForwardDiff(), AutoZygote()]

2-element Vector{ADTypes.AbstractADType}:
 AutoForwardDiff()
 AutoZygote()

To do that, we are going to take gradients of a simple function:

f(x::AbstractArray) = sum(sin, x)

f (generic function with 1 method)

Of course we know the true gradient mapping:

∇f(x::AbstractArray) = cos.(x)

∇f (generic function with 1 method)

DifferentiationInterfaceTest.jl relies with so-called "scenarios", in which you encapsulate the information needed for your test:

• the operator category (:gradient)
• the behavior of the operator (either :in or :out of place)
• the function f
• the input x of the function f
• the reference first-order result res1 of the operator

xv = rand(Float32, 3)
xm = rand(Float64, 3, 2)
scenarios = [
    Scenario{:gradient,:out}(f, xv; res1=∇f(xv)),
    Scenario{:gradient,:out}(f, xm; res1=∇f(xm))
];

Testing

The main entry point for testing is the function test_differentiation. It has many options, but the main ingredients are the following:

julia> test_differentiation(
           backends,  # the backends you want to compare
           scenarios,  # the scenarios you defined,
           correctness=true,  # compares values against the reference
           type_stability=:none,  # checks type stability with JET.jl
           detailed=true,  # prints a detailed test set
       )Test Summary:                                                 | Pass  Total  Time
Testing correctness                                           |   88     88  9.4s
  AutoForwardDiff()                                           |   44     44  6.0s
    gradient                                                  |   44     44  5.9s
      Scenario{:gradient,:out} f : Vector{Float32} -> Float32 |   22     22  3.6s
      Scenario{:gradient,:out} f : Matrix{Float64} -> Float64 |   22     22  2.2s
  AutoZygote()                                                |   44     44  3.4s
    gradient                                                  |   44     44  3.3s
      Scenario{:gradient,:out} f : Vector{Float32} -> Float32 |   22     22  2.7s
      Scenario{:gradient,:out} f : Matrix{Float64} -> Float64 |   22     22  0.7s

If you are too lazy to manually specify the reference, you can also provide an AD backend as the ref_backend keyword argument, which will serve as the ground truth for comparison.

Benchmarking

Once you are confident that your backends give the correct answers, you probably want to compare their performance. This is made easy by the benchmark_differentiation function, whose syntax should feel familiar:

df = benchmark_differentiation(backends, scenarios);

The resulting object is a DataFrame from DataFrames.jl, whose columns correspond to the fields of DifferentiationBenchmarkDataRow: